Lateralization and Symmetry

Initialize NeuroAnalyzer
using NeuroAnalyzer
import CairoMakie
# Quarto sets a default figure size (672 × 480 px), which overrides the sizes of
# NeuroAnalyzer figures: remove it
delete!(CairoMakie.Makie.CURRENT_DEFAULT_THEME, :resolution)
using DataFrames
NeuroAnalyzer.progress_bar = false
eeg = load_neuro("files/eeg/eeg.hdf")

Hemispheric asymmetry of the EEG is the difference in activity between homologous regions of the left and right hemispheres. NeuroAnalyzer provides three measures:

Function Compares Measure
lat_idx() all left vs all right hemisphere channels log-ratio of power at a frequency or band
asy_idx() any two sets of channels (e.g. F4 vs F3) log-ratio and normalized difference of band power
sym_idx() positive vs negative amplitudes of each channel ratio of the number of samples

Selecting Channels of a Hemisphere

The hemisphere of an electrode follows from its label in the 10-20 system: odd numbers are on the left, even numbers on the right, and z electrodes on the midline.

channel_pick() selects channels by region (:frontal, :central, :temporal, :parietal, :occipital) and side (:left, :right); picks are combined with AND, and midline channels are never included:

ch_left = channel_pick(eeg; pick = [:left, :frontal])
ch_right = channel_pick(eeg; pick = [:right, :frontal])
println("Left frontal:  ", ch_left)
println("Right frontal: ", ch_right)
Left frontal:  ["Fp1", "F3", "F7"]
Right frontal: ["Fp2", "F4", "F8"]

channel_cluster() returns predefined clusters of electrodes, e.g. :f1 (left frontal) and :f2 (right frontal); only the channels present in the object are returned:

println("Cluster f1: ", channel_cluster(eeg; cluster = :f1))
println("Cluster f2: ", channel_cluster(eeg; cluster = :f2))
Cluster f1: ["Fp1", "F3", "F7"]
Cluster f2: ["Fp2", "F4", "F8"]

Lateralization Index

The Lateralization Index (LI) is the natural logarithm of the ratio of power in the right and left hemispheres at a given frequency or frequency range:

\[ LI = \ln\left(\frac{P_{right}}{P_{left}}\right) \]

where:
\(P_{right}\) is the power of the right hemisphere channels,
\(P_{left}\) is the power of the left hemisphere channels.

Interpretation:

  • LI > 0: more power in the right hemisphere
  • LI < 0: more power in the left hemisphere
  • LI = 0: symmetric power

lat_idx() detects the hemisphere channels automatically (all left vs all right channels, see channel_pick()), calculates their PSD (Welch’s method by default, method selects another estimator), averages it over epochs and channels, and returns the index for a single frequency (frq = 10) or the mean power over a frequency range (frq = (8, 13)):

for band in [:delta, :theta, :alpha, :beta]
    li = lat_idx(eeg; frq = band_frq(eeg; band = band))
    println(rpad(band, 6), ": LI = ", round(li; digits = 3))
end
delta : LI = -0.203
theta : LI = -0.169
alpha : LI = -0.145
beta  : LI = -0.438

In this recording, power is slightly higher in the left hemisphere in all bands.

Asymmetry Index

asy_idx() compares the mean band power of two sets of channels, ch1 and ch2:

\[ ASI = \ln(P_{ch1}) - \ln(P_{ch2}) \]

\[ NASI = \frac{P_{ch1} - P_{ch2}}{P_{ch1} + P_{ch2}} \]

  • asi: log-ratio of power; positive when ch1 has more power than ch2
  • nasi: normalized difference of power, bounded to \((-1, 1)\), analogous to a contrast ratio

Frontal alpha asymmetry (FAA) is the most widely used asymmetry measure, by convention calculated as \(\ln(P_{right}) - \ln(P_{left})\), typically for F4 and F3. Since alpha power is inversely related to cortical activity, the interpretation is reversed:

  • FAA > 0: more alpha power on the right, i.e. relatively greater left frontal activity; associated with approach motivation and positive affect
  • FAA < 0: more alpha power on the left, i.e. relatively greater right frontal activity; associated with withdrawal motivation and negative affect (e.g. in depression and anxiety)
  • FAA = 0: balanced activity

To follow this convention, the right channels are given as ch1 and the left channels as ch2:

alpha = band_frq(eeg; band = :alpha)
faa = asy_idx(eeg;
              ch1 = "F4",
              ch2 = "F3",
              flim = alpha)
println("FAA (F4/F3): ", round(faa.asi; digits = 3))
println("Normalized:  ", round(faa.nasi; digits = 3))
FAA (F4/F3): -1.561
Normalized:  -0.653

Sets of channels may be compared as well (the power is averaged over the channels of each set):

faa = asy_idx(eeg;
              ch1 = ch_right,
              ch2 = ch_left,
              flim = alpha)
println("FAA (right/left frontal): ", round(faa.asi; digits = 3))
FAA (right/left frontal): -1.069

Alpha asymmetry of all homologous pairs of electrodes:

ch_pairs = [("Fp2", "Fp1"), ("F4", "F3"), ("F8", "F7"), ("C4", "C3"),
         ("T4", "T3"), ("P4", "P3"), ("T6", "T5"), ("O2", "O1")]
df = DataFrame(pair = String[], asi = Float64[], nasi = Float64[])
for (r, l) in ch_pairs
    a = asy_idx(eeg; ch1 = r, ch2 = l, flim = alpha)
    push!(df, ("$r/$l", a.asi, a.nasi))
end
df
8×3 DataFrame
Row pair asi nasi
String Float64 Float64
1 Fp2/Fp1 -1.20448 -0.53864
2 F4/F3 -1.56115 -0.653036
3 F8/F7 -0.719726 -0.345093
4 C4/C3 -1.0042 -0.463765
5 T4/T3 -0.0132956 -0.00664771
6 P4/P3 0.191574 0.0954949
7 T6/T5 0.048832 0.0244111
8 O2/O1 0.157126 0.0784017

The strong asymmetry of the frontal and central pairs should be interpreted with caution: F3 contains frequent transients (see the kurtosis map in the signal statistics tutorial), which increase its power. Asymmetry measures compare power between channels, so any artifact or difference in electrode impedance affecting one side biases the result.

Symmetry Index

The Symmetry Index of a channel is the ratio of the number of non-negative samples to the number of negative samples. It describes the balance of positive and negative deflections of the signal (it does not compare two channels):

  • symmetry index = 1: as many positive as negative samples
  • symmetry index > 1: more positive samples
  • symmetry index < 1: more negative samples

sym_idx() returns a matrix (channels × epochs):

sym_idx(eeg; ch = ["F3", "F4", "O1", "O2"])
4×1 Matrix{Float64}:
 0.9878786466947764
 1.0676924319521848
 1.0026989391995493
 0.9964827726046199

The index depends on the DC offset of the signal; to describe the shape of the signal rather than its offset, remove the DC component first:

eeg_dc = remove_dc(eeg; ch = "eeg")
sym_idx(eeg_dc; ch = ["F3", "F4", "O1", "O2"])
4×1 Matrix{Float64}:
 0.9470273723599248
 1.0001640753183842
 0.9702690638179972
 0.9787822806922619

Applications

  • Emotion and motivation: frontal alpha asymmetry is used in research on emotion regulation and approach/withdrawal motivation; relatively lower left frontal activity (more left frontal alpha) has been associated with depression and anxiety, although the effect is small and inconsistent across studies.
  • Cognitive functions: asymmetry in other bands (e.g. theta, beta, gamma) and other regions reflects the lateralization of attention, memory and language processing.
  • Clinical neurophysiology: a marked asymmetry of the background activity (e.g. a unilateral reduction of alpha or an increase of slow activity) may indicate a focal lesion, stroke or epileptogenic focus.

Practical Considerations

  • Frequency bands: the indices can be calculated for any band (delta, theta, alpha, beta, gamma), depending on the research question.
  • Channels: compare homologous channels (e.g. F3 and F4, C3 and C4) with similar impedances.
  • Reference: asymmetry depends on the reference; a reference located on one side (e.g. a single mastoid) biases the result, and the average reference, linked mastoids or the current source density (Laplacian) are commonly used.
  • Artifacts: remove artifacts (eye movements, muscle activity) before the analysis, since they rarely affect both sides equally.
  • Reliability: use long recordings (several minutes) and average over epochs; asymmetry measured in short segments is unstable.